编程学习biancheng.45soft.com 本站提供了各种在线教程和资料,供大家学习与参考.
编程学习
当前位置: 主页 > VB6 > 界面设计 > VB6 界面设计 菜单编辑器的使用

VB6 界面设计 菜单编辑器的使用

打开菜单编辑器的方法:单击工具菜单再单击菜单编辑器或直接按快捷键(CTRL+E),或单击工具栏上的菜单编辑器图标,窗体上立即出现菜单编辑器对话框。


菜单编辑器对话框形式如下:

菜单编辑器的使用_界面设计_VB6


菜单编辑器对话框有菜单项属性区(称为数据区)、操作按钮区(称为编辑区)和菜单列表区(称为菜单项显示区)。上半部(数据区、编辑区)由用户设定,下半部显示设计的层次结构,左右上下箭头用于调整层次结构,其余按钮功能见名知义。所有菜单仅支持单击(Click)事件。



1.创建菜单项

(1)在标题栏输入该菜单项的文本。(对应属性为Caption),该文本就是在应用程序菜单上出现的名字,如要加热键则在某字符前面加 &。

(2)在名称栏输入程序中要引用该菜单项的名称。(对应属性为Name ),这个属性不会在屏幕上出现。

(3)单击下一个按钮或插入按钮,建立下一个菜单。

(4)复选(Checked)框可使菜单项左边加上“√”(如选中复选框)标记;

(5)有效(Enabled)检查框用于控制菜单是否可被选择使用(选中可以使用);

(6)可见(Visible)检查框决定菜单项是否可见(选中可见);

(7)操纵上下箭头按钮可调整菜单项在菜单列表框中的排列位置;

(8)操纵左右箭头按钮可调整菜单项的层次;

(9)联级菜单项标题前比上一级菜单项多“……”标志。单击确定按钮关闭菜单编辑器。

(10)索引(Index)设置动态菜单时使用。

(11)显示窗口列表(WindowList)选中该项能够自动在某菜单下(一般在窗口菜单下)显示新增的窗口名称(在多文档界面中使用)。



2. 分割菜单项

分割菜单项在应用程序菜单中显示一条水平分割线。建立时在标题栏中输入一个连字符“-”;分隔菜单项也应有名称。建立步骤同创建菜单项。



3. 热键与快捷键

可以为菜单定义热键和快捷键。热键是指能使用Alt键和菜单标题中的带下划线的字母来打开菜单(对顶层菜单而言),对于菜单项则直接按带下划线的字母执行菜单命令。这个带下划线的字母称为热键字符。建立方法是在菜单标题的某个字符前加一个&符号;


快捷键是不需要打开菜单而是直接执行相应菜单项的操作。建立方法是在菜单编辑器的快捷键下拉列表框中选择一个键,则在菜单项标题的右边就会显示快捷键名称。顶层菜单名没有快捷键只能有热键。


[例8.6] 参照Windows的纪事本,建立一个有菜单功能的文本编辑器。


文本编辑器菜单结构如下所示:


标题 名称 快捷键 标题 名称 快捷键
文件 FileMenu   编辑 EditMenu  
…新建 FileNew Ctrl+N …复制 EditCopy Ctrl+C
…打开 FileOpen Ctrl+O …剪切 EditCut Ctrl+X
…保存 FileSave Ctrl+S …粘贴 EditPase Ctrl+V
…另存为 FileSave As        
…退出 FileExit        


菜单编辑器的使用_界面设计_VB6

Dim st As String              '定义一个窗体级变量
Private Sub EditCopy_Click() '单击复制菜单
    st = Text1.SelText   '将选中的内容存放到st变量中
    EditCopy.Enabled = False   '进行复制后,剪切和复制菜单无效
    EditCut.Enabled = False
    EditPaste.Enabled = True   '粘贴菜单有效
End Sub

Private Sub EditCut_Click() '单击剪切菜单
    st = Text1.SelText    '将选中的内容存放到st变量中
    Text1.SelText = ""    '将选中的内容清除,实现了剪切
    EditCopy.Enabled = False
    EditCut.Enabled = False
    EditPaste.Enabled = True
End Sub

Private Sub EditPaste_Click() '单击粘贴菜单
    Text1.Text = Left(Text1, Text1.SelStart) + st + Mid(Text1, Text1.SelStart + 1)
End Sub

Private Sub FileExit_Click() '单击退出菜单
    End
End Sub

Private Sub FileOpen_Click()   '单击打开文件菜单
    On Error GoTo nofile               ' 设置错误陷阱
    CommonDialog1.InitDir = "C:\Windows"    ' 设置属性(可以在设计中完成)
    CommonDialog1.Filter = "文本文件 | *.Txt"
    CommonDialog1.CancelError = True    '按对话框中的取消按钮,将发出错误警告
    CommonDialog1.ShowOpen()            ' 或用Action = 1
    Text1.Text = ""
    Open CommonDialog1.FileName For Input As #1  ' 打开文件进行读操作
    Do While Not EOF(1)
        Line Input #1, inputdata            ' 读一行数据
        Text1.Text = Text1.Text + inputdata + Chr(13) + Chr(10)
    Loop
    Close #1                    ' 关闭文件
    Exit Sub
nofile:  ' 错误处理
    If Err.Number = 32755 Then Exit Sub ' 单击"取消"按钮
End Sub

'在文本框中移动鼠标
Private Sub Text1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
    If Text1.SelText <> "" Then
        EditCut.Enabled = True '当拖动鼠标选中要操作的文本后,剪切、复制菜单有效
        EditCopy.Enabled = True
        EditPaste.Enabled = False
    Else
        EditCut.Enabled = False    ' 当拖动鼠标未选中文本,剪切、复制菜单无效
        EditCopy.Enabled = False
        EditPaste.Enabled = True
    End If
End Sub



编程学习 VB6 界面设计 菜单编辑器的使用 转载请保留此行.谢谢.

VB6